Infrastructure management via Terraform

Terraform is a software for managing external infrastructure. With Terraform, you can manage VMmanager resources - virtual machines (VMs), networks, etc.

Terraform uses the Infrastructure as code (IaC) approach – all commands and settings for resources are transmitted through configuration files. The configuration files use the declarative language HCL (HashiCorp Configuration Language). Read more about Terraform in the official documentation .

Terraform interacts with infrastructure objects using a special set of instructions - a provider. The provider documentation for VMmanager is available at registry.terraform.io and github.com .

Installing Terraform

Standard method

AlmaLinux, CentOS

Run the commands:

yum install -y yum-utils

yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo

yum -y install terraform

Create a separate directory for Terraform:
```
mkdir ./terraform
```

Debian, Ubuntu

Run the commands:

apt-get update && apt-get install -y gnupg software-properties-common curl

curl -fsSL https://apt.releases.hashicorp.com/gpg | apt-key add -

apt-add-repository "deb [arch=amd64] https://apt.releases.hashicorp.com $(lsb_release -cs) main"

sudo apt-get update && sudo apt-get install terraform

Create a separate directory for Terraform:
```
mkdir ./terraform
```

macOS

If the Homebrew packet manager is not installed in the system, install it:

/bin/bash -c "$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/HEAD/install.sh)"

Run the commands:

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

Create a separate directory for Terraform:
```
mkdir ./terraform
```

Windows

Download the Terraform version for Windows.
Unpack the contents of the archive into a separate directory. For example, C:\Apps\Terraform\ .
Add the path to the Terraform directory to the PATH system variable. The order of addition depends on the OS version.

Alternative method

If the Terraform repository is unavailable, you can download the software distribution from the repository mirror. After downloading:

Unpack the contents of the archive into a separate directory.
Add the path to the directory to the PATH system variable.
Command for Linux
```
export PATH=$PATH:/path/to/terraform
```
Comments to the command
/path/to/terraform — path to the Terraform directory

Preparing the configuration

To prepare the configuration, create a main.tf file in the Terraform directory.

An example of a main.tf file to create a VM

# VMmanager provider initialization
terraform {
  required_providers {
    vmmanager6 = {
      source = "usaafko/vmmanager6"
      version = ">= 0.0.25"
    }
  }
}

provider "vmmanager6" {
# Admin e-mail
  pm_email = "admin@example.com"
# Admin password
  pm_password = "secret"
# Platform server URL
  pm_api_url     = "https://vmmanager.example.com"
}

# Description of the resource to be created - virtual machine (VM)
resource "vmmanager6_vm_qemu" "test_vm" {
# VM name
  name = "My_vm"
# VM description
  desc = "Testing Terraform"
# Number of CPU cores
  cores = 1
# Amount of RAM, Mb
  memory = 512
# Disk space
  disk = 5000
# Operating system template id
  os = 1
# VM admin password
  password = "vmsecret"
# cluster id
  cluster = 1
# VM owner. Terraform will create an owner account based on the data
# from the "user" resource and store it in this parameter. Instead of
# the variable you can specify the id of an existing user.
  account = "${vmmanager6_account.user.id}"
# VM domain name
  domain = "test.example.com"
# Resources on which the creation of VMs depends - the physical network,
# pool of IP addresses and the user. Terraform in the first place
# will create the specified objects and then the VM.
  depends_on = [vmmanager6_network.net1, vmmanager6_pool.pool1, vmmanager6_account.user  ]
# From which pool to get the IP address for the VM. Terraform will create
# the pool based on the data from the "pool1" resource and will save it
# in this parameter. Instead of a variable you can specify the id
# of the existing pool.
  ipv4_pools = [ "${vmmanager6_pool.pool1.id}" ]
# Number of IP addresses
  ipv4_number = 1
}

# Description of the resource to be created - physical network
resource "vmmanager6_network" "net1" {
# Network in the format <network address>/<network mask prefix>
  network = "172.31.240.0/20"
# Gateway IP address
  gateway = "172.31.255.254"
# Network description
  desc = "Terraform network"
}

# Description of the resource to be created - IP pool
resource "vmmanager6_pool" "pool1" {
# Pool name
  pool = "terraform"
# Pool description
  desc = "Terraform pool"
# Block of IP addresses included in the pool
  ranges = ["172.31.247.16/30"]
# Dependent resource - the physical network. Terraform will create the pool
# only after the physical network has been created.
  depends_on = [vmmanager6_network.net1]
}

# Description of the resource to be created - user account
resource "vmmanager6_account" "user" {
# User e-mail
  email = "user@example.com"
# User password
  password = "usersecret"
# User role
  role = "@advanced_user"
# User's SSH public key. Optional parameter. 
# Without specifying the SSH key, the user will be able to connect
# to the VM by password only.
  ssh_keys {
# SSH key user name
    name = "user123"
# Contents of the public SSH key
    ssh_pub_key = "ecdsa-sha2-nistp256 AAAAE2VjZ....user@example.com"
  }
}

Creating resources

Initialize the configuration project:

terraform init

If the resource with provider is unavailable, the response will contain an error of the form

│ Error: Failed to query available provider packages
│ 
│ Could not retrieve the list of available versions for provider
│ usaafko/vmmanager6: could not connect to registry.terraform.io: Failed to
│ request discovery document: 403 Forbidden

In this case, you can install the provider locally:

Note

Local installation of the provider is possible only on PCs with Linux OS family.

Run the commands:

mkdir -p ~/.terraform.d/plugins/localhost/usaafko/vmmanager6/0.0.25/linux_amd64/

curl -L https://github.com/usaafko/terraform-provider-vmmanager6/releases/download/v0.0.25/terraform-provider-vmmanager6_0.0.25_linux_amd64.zip -o terraform-provider-vmmanager6.zip

unzip terraform-provider-vmmanager6.zip

mv terraform-provider-vmmanager6_v0.0.25 ~/.terraform.d/plugins/localhost/usaafko/vmmanager6/0.0.25/linux_amd64/terraform-provider-vmmanager6

In the main.tf file, replace the line

source = "usaafko/vmmanager6"

source = "localhost/usaafko/vmmanager6"

Initialize the configuration project:
```
terraform init
```

Check the syntax of the configuration file:
```
terraform validate
```
If the configuration is valid, the response will contain the message:
```
Success! The configuration is valid.
```
Check that the resources will be created with the required configuration:
```
terraform plan
```
The output of the command will list the resources to be created and their properties. If necessary, you can correct the configuration file and run the command again.
Start creating resources:
```
terraform apply
```
To confirm the creation of the resources, type yes and press Enter.

Editing resources

To edit the created resources:

Edit the resource settings in the main.tf file.
Run the command:
```
terraform apply
```
To confirm editing of the resources, type yes and press Enter.

If some resources have already been created, Terraform will not recreate them.

Deleting resources

To delete the created resources, run the command:

terraform destroy

After running the command, the terminal will display the list of resources to be deleted. To confirm deletion, type yes and press Enter.

Note

Resources cannot be recovered after this command is executed.